// Downloaded From https://www.WiseStockTrader.com
_SECTION_BEGIN("AORD Market Trend");

/// Market Trend (Bull & Bear)
//Fibancci Numbers = 1 2 3 5 8 13 21 34 55 89 144 etc....

SetChartOptions(0,chartShowArrows|chartShowDates);

Mt = Foreign("^AORD", "C");

Long_   = Param("Long",   89, 0, 900, 1);
Medium_ = Param("Medium", 55, 0, 100, 1);
Short_  = Param("Short",  13, 0,  50, 1);

//Longterm Bullish or Bearish
L_Mt    = WMA(Mt, Long_);
L_BullT = Mt > L_Mt;
L_BearT = Mt < L_Mt;

//Midterm Bullish or Bearish
M_Mt    = WMA(Mt, Medium_);
M_BullT = Mt > M_Mt;
M_BearT = Mt < M_Mt;

//Shortterm Bullish or Bearish
S_Mt    = WMA(Mt, Short_);
S_BullT = Mt > S_Mt;
S_BearT = Mt < S_Mt;

Trend_Bull = L_BullT + M_BullT + S_BullT; 
Trend_Bear = L_BearT + M_BearT + S_BearT;

DOW = DayOfWeek();

Title = "\n " + Interval( 2 ) + " Chart - " + "AORD Market Trend is currently " +
		EncodeColor(colorBrightGreen) +        
		WriteIf(Trend_Bull == 3, "Low Market Risk", "") +
       WriteIf(Trend_Bull == 2, "Low to Medium Market Risk", "") +
		EncodeColor(colorRed) +  
       WriteIf(Trend_Bear == 3, "High Market Risk", "") +
       WriteIf(Trend_Bear == 2, "High to Medium Market Risk", "") +
		"   (" + Trend_Bull + " , " + Trend_Bear + ")"+
		EncodeColor(colorBlack) +  
       "\n " + Date() + " - " +
       WriteIf( dow == 5, "Friday", 
		WriteIf( dow == 4, "Thursday", 
		WriteIf( dow == 3, "Wednesday", 
		WriteIf( dow == 2, "Tuesday",
		WriteIf( dow == 1, "Monday", "" ) ) ) ) ) +
       "\n"+EncodeColor(colorBlack)+"  Market Trend: "+
		WriteIf(S_BullT,EncodeColor(colorBrightGreen)+
		"  UP  ",WriteIf(S_BearT,EncodeColor(colorRed)+
		" Dwn",EncodeColor(colorYellow)+
       "Flat"))  +
		EncodeColor(colorBlack)+ 
		" | "+
		WriteIf(M_BullT,EncodeColor(colorBrightGreen)+
		"  UP  ",WriteIf(M_BearT,EncodeColor(colorRed)+
		" Dwn",EncodeColor(colorYellow)+
       "Flat"))+  
		EncodeColor(colorBlack)+ 
		" | "+
		WriteIf(L_BullT,EncodeColor(colorBrightGreen)+
		"  UP  ",WriteIf(L_BearT,EncodeColor(colorRed)+
		" Dwn",EncodeColor(colorYellow)+
		"Flat"))+EncodeColor(colorBlack)+
       "\n" + "                             " + 
		EncodeColor(colorRed)+ "  S     "+ 
		EncodeColor(colorBlack)+ "|" +
		EncodeColor(colorBrightGreen)+ "    M    "+ 
		EncodeColor(colorBlack)+ "|"+
		EncodeColor(colorBlue)+ "    L  "+
		EncodeColor(colorBlack) + 
       "\n" + "                           " + 
		EncodeColor(colorRed)+ "    " + Short_ + 
		EncodeColor(colorBlack)+ "     |" +
		EncodeColor(colorBrightGreen)+ "    " + Medium_ + 
		EncodeColor(colorBlack)+ "   |  " +
		EncodeColor(colorBlue)+ Long_ +
		EncodeColor(colorBlack); 

Plot(L_Mt, "Long Market Trend", colorBlue, styleLine);
Plot(M_Mt, "Medium Market Trend", colorBrightGreen, styleLine);
Plot(S_Mt, "Short Market Trend", colorRed, styleLine);
Plot(Foreign("^AORD", "C"), "AORD", colorBlack, styleLine | styleThick);

Plot( 2,"",IIf(Trend_Bull == 3, colorBrightGreen, IIf(Trend_Bull == 2, colorGreen, IIf(Trend_Bull ==1, colorOrange, colorBlack))),styleOwnScale|styleArea|styleNoLabel, -0.5, 100 );
Plot( 4,"",IIf(Trend_Bear == 3, colorRed, IIf(Trend_Bear == 2, colorPink, IIf(Trend_Bear ==1, colorYellow, colorBlack))),styleOwnScale|styleArea|styleNoLabel, -0.5, 100 );

_SECTION_END();