// Downloaded From https://www.WiseStockTrader.com
// AFL code by Edward Pottasch, Jan 2013
xx=BarIndex();x=xx;Lx=LastValue(x);
rightStrength=Param("Fractal Pivot Right side Strength",5,0,50,1); 
leftStrength=Param("Fractal Pivot Left side Strength",10,0,50,1); 
CleanPivots=ParamToggle("Force Pivots to Alternate","Off|On",1);
dispbe123=ParamToggle("Display bearish 123","Off|On",1);
dispbu123=ParamToggle("Display bullish 123","Off|On",1);
dispbeRetraceValues=ParamToggle("Display retrace value (Bearish)","Off|On",1);
dispbuRetraceValues=ParamToggle("Display retrace value (Bullish)","Off|On",1);
dispLabels=ParamToggle("Display Labels","Off|On",1);
entryType=ParamToggle("Entry Type","Regular|Agressive",1);
signalRangeCheck=ParamToggle("Signal Entry Range Limit","Off|On",1);
extendRange=Param("Extended entry range",100,0,500,1);
minRetrace=Param("Retrace Minimum",0.382,0,2,0.01); 
maxRetrace=Param("Retrace Maximum",0.88,0,6,0.01); 

pk=H>Ref(HHV(H,leftStrength),-1) AND Ref(HHV(H,rightStrength),rightStrength)<=H;
tr=L<Ref(LLV(L,leftStrength),-1) AND Ref(LLV(L,rightStrength),rightStrength)>=L;

px0=ValueWhen(pk,x,0); tx0=ValueWhen(tr,x,0);
px1=ValueWhen(pk,x,1); tx1=ValueWhen(tr,x,1);
px2=ValueWhen(pk,x,2); tx2=ValueWhen(tr,x,2);
ph0=ValueWhen(pk,H,0); tl0=ValueWhen(tr,L,0);
ph1=ValueWhen(pk,H,1); tl1=ValueWhen(tr,L,1);
ph2=ValueWhen(pk,H,2); tl2=ValueWhen(tr,L,2);

if(CleanPivots)
{
	pk=IIf((ph0>=ph1 AND tx0>px0 AND px0!=px1) 
	OR (ph1<ph2 AND px2>tx1)
	OR (ph0>=ph1 AND tx0<px0 AND tx0==tx1 AND px0!=px1)
	,False,pk);
	tr=IIf((tl0<=tl1 AND px0>tx0 AND tx0!=tx1) 
	OR (tl1>tl2 AND tx2>px1)
	OR (tl0<=tl1 AND px0<tx0 AND px0==px1 AND tx0!=tx1)
	,False,tr);
	
	px0=ValueWhen(pk,x,0); tx0=ValueWhen(tr,x,0);
	px1=ValueWhen(pk,x,1); tx1=ValueWhen(tr,x,1);
	px2=ValueWhen(pk,x,2); tx2=ValueWhen(tr,x,2);
	ph0=ValueWhen(pk,H,0); tl0=ValueWhen(tr,L,0);
	ph1=ValueWhen(pk,H,1); tl1=ValueWhen(tr,L,1);
	ph2=ValueWhen(pk,H,2); tl2=ValueWhen(tr,L,2);	
}

ll=tr AND tl1<tl2;
hl=tr AND tl1>tl2;
hh=pk AND ph1>ph2;
lh=pk AND ph1<ph2;
dt=pk AND ph1==ph2;
db=tr AND tl1==tl2;

ll_h=IIf(ll,1,0);
hl_h=IIf(hl,2,0);
hh_h=IIf(hh,3,0);
lh_h=IIf(lh,4,0);
dt_h=IIf(dt,5,0);
db_h=IIf(db,6,0);

combi=ll_h+hl_h+lh_h+hh_h+dt_h+db_h;

t0=ValueWhen(combi,combi,0);
t1=ValueWhen(combi,combi,1);
t2=ValueWhen(combi,combi,2);
t3=ValueWhen(combi,combi,3);
t4=ValueWhen(combi,combi,4);
t5=ValueWhen(combi,combi,5);

// bearisch 123 pattern
be123=pk AND t1==4 AND t2==2;
beAx=ValueWhen(be123,tx2);beAy=ValueWhen(be123,tl2);
beBx=ValueWhen(be123,px2);beBy=ValueWhen(be123,ph2);
beCx=ValueWhen(be123,tx1);beCy=ValueWhen(be123,tl1);
beDx=ValueWhen(be123,px1);beDy=ValueWhen(be123,ph1);
beRetrace=(beBy-beCy)/(beBy-beAy);
be123=be123 AND beRetrace>minRetrace AND beRetrace<maxRetrace AND beDy>beCy;
rr=BarsSince(be123)>=0 AND BarsSince(be123)<extendRange;
idx=IIf(rr,xx-ValueWhen(be123,beCx),Null);
if(entryType) aa=(beCy-beAy)/(beCx-beAx);else aa=0;bb=beCy;
aa=ValueWhen(be123,aa);bb=ValueWhen(be123,bb);
beEx=ValueWhen(be123,px1);ii=px1-beCx;beEy=aa*ii+bb;
be123=be123 AND beEy<beDy;
beTrendline=IIf(idx,aa*idx+bb,Null);beValidSignalArea=Flip(be123,Ref(tr,-1));
if(signalRangeCheck) beTrendline=IIf(beValidSignalArea,beTrendline,Null);
Short=Cross(beTrendline,C) AND !IsEmpty(beTrendline);Short=Ref(Short,-1);ShortPrice=O;
Short=ExRem(Short,be123);Sell=0;
 
// bullish 123 pattern
bu123=tr AND t1==2 AND t2==4;
buAx=ValueWhen(bu123,px2);buAy=ValueWhen(bu123,ph2);
buBx=ValueWhen(bu123,tx2);buBy=ValueWhen(bu123,tl2);
buCx=ValueWhen(bu123,px1);buCy=ValueWhen(bu123,ph1);
buDx=ValueWhen(bu123,tx1);buDy=ValueWhen(bu123,tl1);
buRetrace=(buCy-buBy)/(buAy-buBy);
bu123=bu123 AND buRetrace>minRetrace AND buRetrace<maxRetrace AND buDy<buCy;;
rr=BarsSince(bu123)>=0 AND BarsSince(bu123)<extendRange;
idx=IIf(rr,xx-ValueWhen(bu123,buCx),Null);
if(entryType) aa=(buCy-buAy)/(buCx-buAx);else aa=0;bb=buCy;
aa=ValueWhen(bu123,aa);bb=ValueWhen(bu123,bb);
buEx=ValueWhen(bu123,tx1);ii=tx1-buCx;buEy=aa*ii+bb;
bu123=bu123 AND buEy>buDy;
buTrendline=IIf(idx,aa*idx+bb,Null);buValidSignalArea=Flip(bu123,Ref(pk,-1));
if(signalRangeCheck) buTrendline=IIf(buValidSignalArea,buTrendline,Null);
Buy=Cross(C,buTrendline) AND !IsEmpty(buTrendline);Buy=Ref(Buy,-1);BuyPrice=O;
Buy=ExRem(Buy,bu123);Cover=0;
 
GraphXSpace=5;SetChartBkColor(ColorRGB(0,0,0));SetChartOptions(0,chartShowDates);
SetBarFillColor(IIf(C>O,colorGreen,IIf(C<=O,colorRed,colorLightGrey)));
Plot(C,"Price",IIf(C>O,colorDarkGreen,IIf(C<=O,colorDarkRed,colorLightGrey)),64,0,0,0,0);
PlotShapes(shapeSmallCircle*tr,IIf(Lx-ValueWhen(tr,x)>rightStrength,ColorRGB(0,100,0),colorWhite),0,L,-10);
PlotShapes(shapeSmallCircle*pk,IIf(Lx-ValueWhen(pk,x)>rightStrength,ColorRGB(255,0,0),colorWhite),0,H,10);
 
if(dispbe123)
{
    Plot(beTrendline,"",ColorRGB(100,0,0),styleDots|styleNoLine,0,0,0,0);
    PlotShapes(IIf(Short,shapeSmallDownTriangle,shapeNone),colorRed,0,H,IIf(Short AND Sell,-30,-15));   
    PlotShapes(IIf(Short,shapeSmallCircle,shapeNone),colorWhite,0,ShortPrice,0);    
}
if(dispbu123)
{
    Plot(buTrendline,"",ColorRGB(0,100,0),styleDots|styleNoLine,0,0,0,0);   
    PlotShapes(IIf(Buy,shapeUpArrow,shapeNone),colorDarkGreen,0,L,-15);
    PlotShapes(IIf(Buy,shapeSmallCircle,shapeNone),colorWhite,0,BuyPrice,0);
}
  
abcdy_up=27;
abcdy_dn=15;
function GetVisibleBarCount() 
{
    lvb=Status("lastvisiblebar");
    fvb=Status("firstvisiblebar");
    return Min(lvb-fvb,BarCount-fvb);
} 
function GfxConvertPixelsToBarX(Pixels)
{
    lvb=Status("lastvisiblebar");
    fvb=Status("firstvisiblebar");
    pxchartleft=Status("pxchartleft");
    pxchartwidth=Status("pxchartwidth");
    fac=pxchartwidth/Pixels;
    bar=(lvb-fvb)/fac;
    return Nz(bar);
} 
function GfxConvertPixelToValueY(Pixels) 
{
    local Miny,Maxy,pxchartbottom,pxchartheight;
    Miny=Status("axisminy");
    Maxy=Status("axismaxy");
    pxchartbottom=Status("pxchartbottom");
    pxchartheight=Status("pxchartheight");
    fac=pxchartheight/Pixels;
    Value=(Maxy-Miny)/fac;
    return Nz(Value);
} 
function GfxConvertBarToPixelX(bar) 
{ 
    lvb=Status("lastvisiblebar"); 
    fvb=Status("firstvisiblebar"); 
    pxchartleft=Status("pxchartleft"); 
    pxchartwidth=Status("pxchartwidth"); 
    return Nz(pxchartleft+bar*pxchartwidth/(lvb-fvb+1)); 
} 
function GfxConvertValueToPixelY(value) 
{
    local Miny,Maxy,pxchartbottom,pxchartheight; 
    Miny=Status("axisminy");
    Maxy=Status("axismaxy");
    pxchartbottom=Status("pxchartbottom");
    pxchartheight=Status("pxchartheight");
    return Nz(pxchartbottom-floor(0.5+(Value-Miny)*pxchartheight/(Maxy-Miny))); 
} 
AllVisibleBars=GetVisibleBarCount();
fvb=Status("firstvisiblebar");
abcdy_up=GfxConvertPixelToValueY(abcdy_up);
abcdy_dn=GfxConvertPixelToValueY(abcdy_dn);
 
for(i=0;i<AllVisibleBars;i++) 
{
	if(ll[i+fvb] AND dispLabels)
	{
		lvix=i+fvb;GfxSelectFont("Tahoma",8,500); GfxSetBkMode(1); 
		GfxSetTextColor(colorYellow);GfxTextOut("LL",GfxConvertBarToPixelX(i)-3,GfxConvertValueToPixelY(L[lvix]-abcdy_dn)); 
		GfxSetTextColor(colorYellow);GfxTextOut(""+L[lvix],GfxConvertBarToPixelX(i)-3,GfxConvertValueToPixelY(L[lvix]-2*abcdy_dn)); 
	}
	if(hl[i+fvb] AND dispLabels)
	{
		lvix=i+fvb;GfxSelectFont("Tahoma",8,500); GfxSetBkMode(1); 
		GfxSetTextColor(colorYellow);GfxTextOut("HL",GfxConvertBarToPixelX(i)-3,GfxConvertValueToPixelY(L[lvix]-abcdy_dn)); 
		GfxSetTextColor(colorYellow);GfxTextOut(""+L[lvix],GfxConvertBarToPixelX(i)-3,GfxConvertValueToPixelY(L[lvix]-2*abcdy_dn)); 
	}	
	if(db[i+fvb] AND dispLabels)
	{
		lvix=i+fvb;GfxSelectFont("Tahoma",8,500); GfxSetBkMode(1); 
		GfxSetTextColor(colorYellow);GfxTextOut("DB",GfxConvertBarToPixelX(i)-3,GfxConvertValueToPixelY(L[lvix]-abcdy_dn)); 
		GfxSetTextColor(colorYellow);GfxTextOut(""+L[lvix],GfxConvertBarToPixelX(i)-3,GfxConvertValueToPixelY(L[lvix]-2*abcdy_dn)); 
	}		
	if(hh[i+fvb] AND dispLabels)
	{
		lvix=i+fvb;GfxSelectFont("Tahoma",8,500); GfxSetBkMode(1); 
		GfxSetTextColor(colorYellow);GfxTextOut("HH",GfxConvertBarToPixelX(i)-5,GfxConvertValueToPixelY(H[lvix]+abcdy_up)); 
		GfxSetTextColor(colorYellow);GfxTextOut(""+H[lvix],GfxConvertBarToPixelX(i)-5,GfxConvertValueToPixelY(H[lvix]+1.57*abcdy_up)); 
	}	
	if(lh[i+fvb] AND dispLabels)
	{
		lvix=i+fvb;GfxSelectFont("Tahoma",8,500); GfxSetBkMode(1); 
		GfxSetTextColor(colorYellow);GfxTextOut("LH",GfxConvertBarToPixelX(i)-5,GfxConvertValueToPixelY(H[lvix]+abcdy_up));
		GfxSetTextColor(colorYellow);GfxTextOut(""+H[lvix],GfxConvertBarToPixelX(i)-5,GfxConvertValueToPixelY(H[lvix]+1.57*abcdy_up));
	}	
	if(dt[i+fvb] AND dispLabels)
	{
		lvix=i+fvb;GfxSelectFont("Tahoma",8,500); GfxSetBkMode(1); 
		GfxSetTextColor(colorYellow);GfxTextOut("DT",GfxConvertBarToPixelX(i)-5,GfxConvertValueToPixelY(H[lvix]+abcdy_up)); 
		GfxSetTextColor(colorYellow);GfxTextOut(""+H[lvix],GfxConvertBarToPixelX(i)-5,GfxConvertValueToPixelY(H[lvix]+1.57*abcdy_up)); 
	}		
    if(be123[i+fvb] AND dispbe123)
    {
        GfxSetOverlayMode(1);
        GfxSelectPen(ColorRGB(100,0,0),2); 
        GfxSelectSolidBrush(ColorRGB(20,0,0));  
        lvix=i+fvb;
        GfxSetBkMode(1);GfxSetOverlayMode(1);GfxSelectPen(ColorRGB(100,0,0),1,1); 
        GfxMoveTo(GfxConvertBarToPixelX(i-(beDx[lvix]-beCx[lvix])),GfxConvertValueToPixelY(beCy[lvix]));
        GfxLineTo(GfxConvertBarToPixelX(i),GfxConvertValueToPixelY(beDy[lvix])); 
        GfxMoveTo(GfxConvertBarToPixelX(i-(beDx[lvix]-beBx[lvix])),GfxConvertValueToPixelY(beBy[lvix]));
        GfxLineTo(GfxConvertBarToPixelX(i),GfxConvertValueToPixelY(beDy[lvix]));
        GfxPolygon(
        GfxConvertBarToPixelX(i-(beDx[lvix]-beAx[lvix])),GfxConvertValueToPixelY(beAy[lvix]),
        GfxConvertBarToPixelX(i-(beDx[lvix]-beBx[lvix])),GfxConvertValueToPixelY(beBy[lvix]),
        GfxConvertBarToPixelX(i-(beDx[lvix]-beCx[lvix])),GfxConvertValueToPixelY(beCy[lvix]));      
        GfxSelectFont("Tahoma",10,500);GfxSetBkMode(1);         
        GfxSetTextColor(ColorRGB(200,0,0));GfxTextOut("1",GfxConvertBarToPixelX(i-(beDx[lvix]-beBx[lvix]))-7,GfxConvertValueToPixelY(beBy[lvix]+1.5*abcdy_up)); 
        GfxSetTextColor(ColorRGB(200,0,0));GfxTextOut("2",GfxConvertBarToPixelX(i-(beDx[lvix]-beCx[lvix]))-7,GfxConvertValueToPixelY(beCy[lvix]-1.6*abcdy_dn)); 
        GfxSetTextColor(ColorRGB(200,0,0));GfxTextOut("3",GfxConvertBarToPixelX(i-(beDx[lvix]-beDx[lvix]))-7,GfxConvertValueToPixelY(beDy[lvix]+1.5*abcdy_up));
        Plot(LineArray(beCx[lvix],beCy[lvix],beEx[lvix],beEy[lvix],0,True ),"",ColorRGB(100,0,0),styleDashed);
        if(dispbeRetraceValues)
        {
            GfxSelectFont("Tahoma",8,650); GfxSetBkMode(2);GfxSetOverlayMode(1);GfxSetBkColor(colorDarkRed);GfxSetTextColor(colorWhite);
            GfxTextOut(""+Prec(beRetrace[lvix],2),GfxConvertBarToPixelX(i-(beDx[lvix]-(beAx[lvix]+beCx[lvix])/2)),GfxConvertValueToPixelY((beAy[lvix]+beCy[lvix])/2));
        }           
    }
    if(bu123[i+fvb] AND dispbu123)
    {
        GfxSetOverlayMode(1);
        GfxSelectPen(ColorRGB(0,100,0),2); 
        GfxSelectSolidBrush(ColorRGB(0,20,0));  
        lvix=i+fvb;
        GfxSetBkMode(1);GfxSetOverlayMode(1);GfxSelectPen(ColorRGB(0,100,0),1,1); 
        GfxMoveTo(GfxConvertBarToPixelX(i-(buDx[lvix]-buCx[lvix])),GfxConvertValueToPixelY(buCy[lvix]));
        GfxLineTo(GfxConvertBarToPixelX(i),GfxConvertValueToPixelY(buDy[lvix])); 
        GfxMoveTo(GfxConvertBarToPixelX(i-(buDx[lvix]-buBx[lvix])),GfxConvertValueToPixelY(buBy[lvix]));
        GfxLineTo(GfxConvertBarToPixelX(i),GfxConvertValueToPixelY(buDy[lvix]));
        GfxPolygon(
        GfxConvertBarToPixelX(i-(buDx[lvix]-buAx[lvix])),GfxConvertValueToPixelY(buAy[lvix]),
        GfxConvertBarToPixelX(i-(buDx[lvix]-buBx[lvix])),GfxConvertValueToPixelY(buBy[lvix]),
        GfxConvertBarToPixelX(i-(buDx[lvix]-buCx[lvix])),GfxConvertValueToPixelY(buCy[lvix]));          
        GfxSelectFont("Tahoma",10,500);GfxSetBkMode(1); 
        GfxSetTextColor(ColorRGB(0,200,0));GfxTextOut("1",GfxConvertBarToPixelX(i-(buDx[lvix]-buBx[lvix]))+3,GfxConvertValueToPixelY(buBy[lvix]-1.6*abcdy_dn)); 
        GfxSetTextColor(ColorRGB(0,200,0));GfxTextOut("2",GfxConvertBarToPixelX(i-(buDx[lvix]-buCx[lvix]))+3,GfxConvertValueToPixelY(buCy[lvix]+1.5*abcdy_up)); 
        GfxSetTextColor(ColorRGB(0,200,0));GfxTextOut("3",GfxConvertBarToPixelX(i-(buDx[lvix]-buDx[lvix]))+3,GfxConvertValueToPixelY(buDy[lvix]-1.6*abcdy_dn)); 
        Plot(LineArray(buCx[lvix],buCy[lvix],buEx[lvix],buEy[lvix],0,True ),"",ColorRGB(0,100,0),styleDashed);
        if(dispbuRetraceValues)
        {       
            GfxSelectFont("Tahoma",8,650); GfxSetBkMode(2);GfxSetOverlayMode(1);GfxSetBkColor(colorDarkGreen);GfxSetTextColor(colorWhite);
            GfxTextOut(""+Prec(buRetrace[lvix],2),GfxConvertBarToPixelX(i-(buDx[lvix]-(buAx[lvix]+buCx[lvix])/2)),GfxConvertValueToPixelY((buAy[lvix]+buCy[lvix])/2));
        }           
    }
}